; file firlib\src\fir_sp_asm_softPipeline.s
; brief FIR filtering function in C6600 assembler with manual optimization
; (single precision IEEE754)
; Advices for assembler procedure development :
; - 1 : kernel loop length is greater or equal to B instruction execution time
; - 2 : check for data loading in a first time 
; author 
; date 

PROLOG_LENGTH .equ	1
	
	.global fir_sp_asm_softPipeline

fir_sp_asm_softPipeline:
				;int i, j;
				MV				A8,A0		;i<nyk
												
L1:				; input array loop			
				;for (i=0; i<nyk; i++) {
				;	tmp = 0;
				ZERO			A5		
				SUB				B6,PROLOG_LENGTH,A1			
				MV				A4,A19
				MV				B4,B19					
											
L2:				; FIR filter algorithm - dot product	
				; software pipeline
; prolog
L2_P1:			LDW				*A19++,A3				
	||			LDW				*B19++,B9				
				NOP				;free slot
				NOP				;free slot
				NOP				;free slot	
				NOP				;free slot				

L2_P2:			LDW				*A19++,A3				
	||			LDW				*B19++,B9					
	||			MPYSP			A3,B9,A17
				NOP				;free slot
				NOP				;free slot
				NOP				;free slot
; kernel loop
L2_KLOOP:		
		[A1] 	BDEC			L2_KLOOP,A1		
		[A1]	LDW				*A19++,A3				
	||	[A1] 	LDW				*B19++,B9					
	||	[A1] 	MPYSP			A3,B9,A17
	||	[A1]	FADDSP			A17,A5,A5
				NOP				;free slot
				NOP				;free slot
				NOP				;free slot
				NOP				;free slot	
; epilog
L2_E1:			MPYSP			A3,B9,A17
	||			FADDSP			A17,A5,A5	
				NOP				;free slot
				NOP				;free slot
				NOP				;free slot				
L2_E2:			FADDSP			A17,A5,A5	
				NOP				;free slot
				NOP				;free slot	
				; end of FIR filter algorithm - dot product	
				
				STW				A5,*A6++	;yk(i) = tmp;
				ADD				A4,4,A4  	;i+j (float -> 4b)										
		[A0]	BDEC			L1,A0
				NOP				5
				; end of input array loop	
						
				B				B3
				NOP				5
				; end of fir_sp_asm procedure